File:Bessel Beam - Self healing.ogg
Original file (Ogg Theora video file, length 3.4 s, 968 × 531 pixels, 6.21 Mbps, file size: 2.52 MB)
Captions
Summary[edit]
DescriptionBessel Beam - Self healing.ogg |
English: Comparison between a Gaussian and a Bessel beam when an obstacle is inserted in the path.
Bessel beams are said to be "self-healing" because, if you put a small obstacle in their course, the result will still look very much like a Bessel beam. |
Date | |
Source | https://twitter.com/j_bertolotti/status/1535222926227668992 |
Author | Jacopo Bertolotti |
Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 13.0 code[edit]
\[Lambda]0 = 0.25; k0 =
N[(2 \[Pi])/\[Lambda]0]; (*The wavelength in vacuum is set to 1, so all lengths are now in units of wavelengths*)
\[Delta] = \[Lambda]0/10; \[CapitalDelta] = 60*\[Lambda]0; (*Parameters for the grid*)
ReMapC[x_] := RGBColor[(2 x - 1) UnitStep[x - 0.5], 0, (1 - 2 x) UnitStep[0.5 - x]]; \[Sigma] = 20 \[Lambda]0; d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
imn = Table[ Chop[5 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d))], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}]; (*Imaginary part of the refractive index (used to emulate absorbing boundaries)*)
dim = Dimensions[imn][[1]];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)
f = 10;
sourcef1[x_, y_] :=(*\[ExponentialE]^(-(x^2/(2 \[Sigma]^2)))*) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y) E^(-I k0/(2 f) x^2);
\[Phi]in1 = Table[Chop[sourcef1[x, y]], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
f2 = 2;
sourcef2[x_, y_] :=(*\[ExponentialE]^(-(x^2/(2 \[Sigma]^2)))*) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y) E^(-I k0/(2 f2) Abs[x]);
\[Phi]in2 = Table[Chop[sourcef2[x, y]], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}]; (*Discretized source*)
frames = Table[
ren = Table[ If[-(\[CapitalDelta]/50) < x + shift < \[CapitalDelta]/50 && -\[CapitalDelta]/400 < y + \[CapitalDelta]/4 < \[CapitalDelta]/400, 2 I, 1], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
n = ren + I imn;
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in1]; (*Right-hand side of the equation we want to solve*)
\[Phi] = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
b2 = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in2]; (*Right-hand side of the equation we want to solve*)
\[Phi]2 = Partition[LinearSolve[M, b2], dim]; (*Solve the linear system*)
Grid[{{
Show[ImageAdd[
ArrayPlot[
Transpose[(Re@\[Phi]/Max[Abs@\[Phi][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], DataReversed -> True, Frame -> False, PlotRange -> {-0.5, 0.5}, LabelStyle -> {Black, Bold}, ColorFunctionScaling -> True, ColorFunction -> ReMapC, ClippingStyle -> {Blue, Red}],
ArrayPlot[Transpose[Im@ren/1] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False]
], PlotLabel -> "Gaussian beam", LabelStyle -> {Black, Bold, FontSize -> 26}, ImageSize -> Medium]
,
Show[ImageAdd[
ArrayPlot[
Transpose[(Re@\[Phi]2/Max[Abs@\[Phi]2[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], DataReversed -> True, Frame -> False, PlotRange -> {-0.5, 0.5}, LabelStyle -> {Black, Bold}, ColorFunctionScaling -> True, ColorFunction -> ReMapC, ClippingStyle -> {Blue, Red}]
,
ArrayPlot[Transpose[Im@ren/1] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False]
], PlotLabel -> "Bessel beam", LabelStyle -> {Black, Bold, FontSize -> 26}, ImageSize -> Medium]
}}]
, {shift, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[CapitalDelta]/50}];
ListAnimate[frames]
Licensing[edit]
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 09:46, 14 June 2022 | 3.4 s, 968 × 531 (2.52 MB) | Berto (talk | contribs) | Uploaded own work with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
Transcode status
Update transcode statusMetadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Image title | Created with the Wolfram Language : www.wolfram.com |
---|---|
Software used | Lavf58.29.100 |